{ config
, lib
, inputs
, self
, pkgs
, ...
}:

with lib;
let
  cfg = config.my.programs.nix;
in
{
  options.my.programs.nix = {
    gc = {
      enable = mkEnableOption "nix-gc";
      minimumFreedGB = mkOption {
        default = 32;
        type = types.int;
        apply = number: toString (number * 1024 * 1024 * 1024);
      };
    };
    optimise.enable = mkEnableOption "nix-optimise";
  };

  config.nix = {
    nixPath = [ "nixpkgs=${inputs.nixpkgs}" ];

    package = inputs.nix-super.packages.${pkgs.system}.default;

    extraOptions = "experimental-features = nix-command flakes";

    gc = {
      automatic = cfg.gc.enable;
      options = "--max-freed ${cfg.gc.minimumFreedGB} --delete-older-than 14d";
      dates = "weekly";
    };

    optimise = {
      automatic = cfg.optimise.enable;
      dates = [ "weekly" ];
    };

    registry = {
      master-upstream.to = {
        type = "github";
        owner = "nixos";
        repo = "nixpkgs";
      };
      master.flake = inputs.master;
      nixpkgs.flake = inputs.nixpkgs;
      stable.flake = inputs.stable;
      dotfiles.flake = self;
      default.flake = self;
    };

    settings = {
      substituters = [
        "https://cache.nixos.org/"
      ];
      trusted-public-keys = [
        "cache.nixos.org-1:6NCHdD59X431o0gWypbMrAURkbJ16ZPMQFGspcDShjY="
      ];

      trusted-users = [ "root" "@wheel" ];
    };
  };
}