dotfiles/overlays/wayland.nix

_:

final: prev: {
  neovide-hyprland = final.symlinkJoin {
    name = "neovide-hyprland-${final.neovide.version}";
    paths = [ final.neovide ];
    nativeBuildInputs = [ final.makeWrapper ];
    postBuild = ''
      rm $out/bin/neovide
      makeWrapper ${final.neovide}/bin/neovide $out/bin/neovide --set WINIT_UNIX_BACKEND x11
    '';
    meta = final.neovide.meta // {
      mainProgram = "neovide";
    };
  };
  logseq-wayland = prev.symlinkJoin {
    name = "logseq-wayland";
    paths = [ prev.logseq ];
    nativeBuildInputs = [ prev.makeWrapper ];
    postBuild = ''
      wrapProgram $out/bin/logseq \
        --add-flags "--socket=wayland --enable-features=UseOzonePlatform --ozone-platform=wayland"
    '';
  };

  waybar-hyprland = prev.waybar.overrideAttrs (old: {
    pname = "${old.pname}-hyprland";
    postPatch = old.postPatch or "" + ''
      sed -i 's,zext_workspace_handle_v1_activate(workspace_handle_);,const std::string command = "${final.hyprland}/bin/hyprctl dispatch workspace " + name_;\n\tsystem(command.c_str());,g' src/modules/wlr/workspace_manager.cpp
    '';
    mesonFlags = old.mesonFlags or [ ] ++ [ "-Dexperimental=true" ];
  });
}