dotfiles/flake.nix

{
  description = "My awesome system config";

  inputs = {
    # Nix
    agenix.inputs.nixpkgs.follows = "nixpkgs";
    agenix.url = "github:ryantm/agenix";

    devshell.url = "github:numtide/devshell";

    disko.url = "github:nix-community/disko";

    flake-parts.url = "github:hercules-ci/flake-parts";
    flake-utils.url = "github:numtide/flake-utils";

    home-manager.inputs.nixpkgs.follows = "nixpkgs";
    home-manager.url = "github:nix-community/home-manager";

    impermanence.url = "github:nix-community/impermanence";

    master.url = "github:nixos/nixpkgs";
    nixpkgs.url = "github:nixos/nixpkgs/nixpkgs-unstable";
    stable.url = "github:nixos/nixpkgs/nixos-24.05";

    pre-commit-hooks.url = "github:cachix/pre-commit-hooks.nix";

    nur.url = "github:nix-community/NUR";

    nix-index-database.url = "github:Mic92/nix-index-database";
    nix-index-database.inputs.nixpkgs.follows = "nixpkgs";

    nixos-facter-modules.url = "github:numtide/nixos-facter-modules";

    nix-monitored.url = "github:ners/nix-monitored";
    nix-monitored.inputs.nixpkgs.follows = "nixpkgs";

    # Programs
    timers.url = "git+https://gitea.moritzboeh.me/moritz/timers.git";

    # Neovim
    neovim-nightly-overlay.url = "github:nix-community/neovim-nightly-overlay";

    nixvim.url = "github:nix-community/nixvim";
    nixvim.inputs.devshell.follows = "devshell";
    nixvim.inputs.flake-parts.follows = "flake-parts";
    nixvim.inputs.home-manager.follows = "home-manager";

    # river
    river.url = "git+https://github.com/riverwm/river?submodules=1";
    river.flake = false;

    # Hyprland
    hypr-contrib.url = "github:hyprwm/contrib";
    hyprland = {
      type = "git";
      url = "https://github.com/hyprwm/Hyprland";
      submodules = true;
    };

    # Laptop
    asus-touchpad-numpad-driver.url = "github:MoritzBoehme/asus-touchpad-numpad-driver/german-layout";
    asus-touchpad-numpad-driver.flake = false;

    # Firefox user.js
    arkenfox-userjs.url = "github:arkenfox/user.js";
    arkenfox-userjs.flake = false;

    ghostty.url = "git+ssh://git@github.com/ghostty-org/ghostty";
  };

  outputs = inputs@{ self, flake-parts, ... }:
    flake-parts.lib.mkFlake { inherit inputs; } {
      debug = true; # NOTE: for nixd
      imports = [
        inputs.pre-commit-hooks.flakeModule
        inputs.devshell.flakeModule
      ];

      systems = [ "x86_64-linux" ];
      perSystem = { config, self', inputs', pkgs, system, ... }: {
        devshells.default = {
          devshell.startup.pre-commit-hook.text = config.pre-commit.installationScript;
          commands = [
            {
              name = "agenix";
              help = "wrapper around agenix";
              command = ''
                sudo EDITOR="${pkgs.lib.getExe pkgs.vim}" ${pkgs.lib.getExe' inputs'.agenix.packages.default "agenix"} --identity /etc/ssh/ssh_host_ed25519_key "$@"
              '';
            }
            {
              name = "vim-startuptime";
              help = "test vim startup time";
              command = "${pkgs.lib.getExe pkgs.hyperfine} --warmup 5 --prepare 'sleep 2' 'vim -c exit'";
            }
          ];
          packages = with pkgs; [
            stylua
            sumneko-lua-language-server
            nixpkgs-fmt
            nh
          ];
        };

        pre-commit = {
          check.enable = true;
          settings = {
            hooks = {
              nixpkgs-fmt.enable = true;
              statix.enable = true;
              shellcheck.enable = true;
              stylua.enable = true;
            };
          };
        };

        legacyPackages = pkgs;

      };

      flake = {
        lib = inputs.nixpkgs.lib.extend
          (self: _: { my = import ./lib { lib = self; }; });

        nixosConfigurations = self.lib.my.mapModules
          (path: self.lib.nixosSystem {
            inherit (self) lib;
            specialArgs = {
              inherit inputs self;
            };
            modules =
              [
                ./modules
                {
                  home-manager = {
                    useGlobalPkgs = true;
                    useUserPackages = true;
                    extraSpecialArgs = { inherit inputs self; };
                    sharedModules = [
                      inputs.nixvim.homeManagerModules.nixvim
                    ];
                  };
                }
                inputs.agenix.nixosModules.age
                inputs.disko.nixosModules.default
                inputs.home-manager.nixosModule
                inputs.impermanence.nixosModules.impermanence
                inputs.nix-index-database.nixosModules.nix-index
                inputs.nixos-facter-modules.nixosModules.facter
                path
              ];
          })
          ./hosts;

        templates = {
          python = {
            description = "Simple poetry shell.nix";
            path = ./templates/python;
          };
          rust = {
            description = "Crane + Fenix flake with mold for faster local builds.";
            path = ./templates/rust;
          };
        };
      };
    };

  nixConfig = {
    extra-substituters = [
      # "https://hyprland.cachix.org"
      "https://nix-community.cachix.org"
      "https://pre-commit-hooks.cachix.org"
      # "https://ghostty.cachix.org"
      "https://cache.lix.systems"
    ];
    extra-trusted-public-keys = [
      # "hyprland.cachix.org-1:a7pgxzMz7+chwVL3/pzj6jIBMioiJM7ypFP8PwtkuGc="
      "nix-community.cachix.org-1:mB9FSh9qf2dCimDSUo8Zy7bkq5CX+/rkCWyvRCYg3Fs="
      "pre-commit-hooks.cachix.org-1:Pkk3Panw5AW24TOv6kz3PvLhlH8puAsJTBbOPmBo7Rc="
      # "ghostty.cachix.org-1:QB389yTa6gTyneehvqG58y0WnHjQOqgnA+wBnpWWxns="
      "cache.lix.systems:aBnZUw8zA7H35Cz2RyKFVs3H4PlGTLawyY5KRbvJR8o="
    ];
  };
}